home *** CD-ROM | disk | FTP | other *** search
/ Digital News 2 / Digital_News_2_1988_-_de_Side_B.d64 / datei 64 (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  2KB  |  65 lines
  1. 20 open15,8,15:poke53280,6:poke53281,6:
  2. 30 print"[147]   ****   datei 64[146]   ****"
  3. 35 print"    (c) 1985 klaus raczek"
  4. 36 print"    *** menue[146] ***"
  5. 40 print"   1[146]- kartei laden"
  6. 50 print"   2[146]- kartei speichern"
  7. 60 print"   3[146]- daten eingeben"
  8. 70 print"   4[146]- daten suchen"
  9. 80 print"   5[146]- daten aendern"
  10. 90 print"   6[146]- daten loeschen"
  11. 100 print"   7[146]- maske erstellen"
  12. 110 print"   8[146]- programm beenden"
  13. 120 print"    welche nummer ";:ch=0:inputch:ch=int(ch):poke2,ch:ifch=8thenend
  14. 130 ifch<1orch>7then30
  15. 135 ifch=1orch=7thenclr:ch=peek(2):open15,8,15
  16. 140 onchgosub200,300,400,500,600,700,900
  17. 150 print"taste druecken":poke198,0:wait198,1:goto30
  18. 200 print"[147]name der kartei";:inputa$
  19. 205 open1,8,2,a$+",s,r":gosub800
  20. 210 input#1,fe,n,le:dimfe$(fe),s$(fe),da$(le,fe)
  21. 215 forx=1tofe:input#1,fe$(x):next
  22. 220 fori=0ton-1:forx=1tofe
  23. 230 input#1,da$(i,x):next:next:close1:gosub800:return
  24. 300 print"[147]name der kartei";:inputa$
  25. 305 open1,8,2,a$+",s,w":gosub800
  26. 310 print#1,fe:print#1,n:print#1,le
  27. 315 forx=1tofe:print#1,fe$(x)" ":next
  28. 320 fori=0ton-1:forx=1tofe
  29. 330 print#1,da$(i,x)" ":next:next
  30. 340 close1:gosub800:return
  31. 400 print"[147]daten eingeben":l=0:forx=1tofe
  32. 410 print""fe$(x)"[146]: ";:inputda$(n,x):l=l+len(da$(n,x)):next
  33. 420 ifl=0thenn=n-1
  34. 430 n=n+1:return
  35. 500 print"[147]suchen:"
  36. 505 fori=1tofe:print""fe$(i)"[146]: ";:s$(i)="":inputs$(i):s(i)=len(s$(i)):next
  37. 515 ei=0:forx=0ton-1:ff=0:fori=1tofe
  38. 520 ifleft$(da$(x,i),s(i))<>s$(i)thenff=1
  39. 530 next:ifff=0goto560
  40. 535 next:ifei=1thenreturn
  41. 540 print"eintrag nicht gefunden":return
  42. 560 iffl=1thenreturn
  43. 565 print"[147]eintrag gefunden:"
  44. 570 forj=1tofe:print""fe$(j)"[146]: "tab(15)da$(x,j):next:ei=1
  45. 590 print"taste druecken":poke198,0:wait198,1:ifx<ngoto535
  46. 595 return
  47. 600 print"[147]aendern:":print"suchen":fl=1:gosub505:fl=0
  48. 610 ifx>nthenreturn
  49. 630 fori=1tofe:print""fe$(i)"[146]:":print"  "da$(x,i):input"[145]";da$(x,i):next:return
  50. 700 print"[147]eintrag loeschen":print"suchen":gosub505
  51. 710 print"loeschen (j/n)"
  52. 720 geta$:ifa$=""then720
  53. 730 ifa$="j"then790
  54. 740 ifa$<>"n"then720
  55. 750 return
  56. 790 fori=1tofe:da$(x,i)=da$(n-1,i):da$(n-1,i)="":next:n=n-1:return
  57. 800 input#15,a,a$:ifa=0thenreturn
  58. 810 printa$:return
  59. 900 clr:open15,8,15:print"[147]eingabemaske erstellen:"
  60. 910 input"wieviele felder";fe
  61. 920 dimfe$(fe),s$(fe):print"namen und mittlere laengen der felder   eingeben:"
  62. 930 le=0:fori=1tofe:printi;:inputfe$(i),x:le=le+x:next
  63. 940 le=((fre(x)+65536)/(le+fe*3+3)):dimda$(le,fe)
  64. 950 print"es ist platz fuer"int(le)"datensaetze.":goto150
  65.